KpyM Telnet/SSH Server - Forum
Installer
Pedro Installer
 
The good thing about this software is that it is opensource.

However, I couldn't find the source code or description on how to generate the installer.

So, how does one create the installation program?

Thanks.


Kroum Grigorov
 
Inno Setup

bellow the installer script

; -- kts.iss --

[Setup]
AppName=KpyM Telnet/SSH Server v1.19c
AppVerName=KpyM Telnet/SSH Server v1.19c
AppCopyright=Copyright (c) 2002-2011 Kroum Grigorov
DefaultDirName={pf}\KTS
DefaultGroupName=KTS
SourceDir=E:\kpym\Projects\verish\release\kts119c\

AppVersion=1.19c
OutputBaseFilename=kts119c

LicenseFile=License.txt
OutputDir=E:\kpym\Projects\verish\release\
PrivilegesRequired=admin
DisableReadyMemo=yes
DisableReadyPage=yes
DisableStartupPrompt=yes
AppContact=Kroum Grigorov
AppSupportURL=http://www.kpym.com/


[Types]
Name: main; Description: KpyM Telnet/SSH Server; Flags: iscustom

[Components]
Name: main; Description: KpyM Telnet/SSH Server Main Files; Types: main; Flags: fixed
Name: source; Description: KpyM Telnet/SSH Server Source Files



[Dirs]
Name: {app}\log
Name: {app}\log\active-sessions
Name: {app}\log\ip-ban

[Files]
Source: *; DestDir: {app}; Components: main
Source: subsystems\*; DestDir: {app}\subsystems; Components: main
Source: scripts\*; DestDir: {app}\scripts; Components: main
Source: sources\*; DestDir: {app}\sources; Components: source
Source: sources\out\*; DestDir: {app}\sources\out; Components: source
Source: sources\shared\*; DestDir: {app}\sources\shared; Components: source
Source: sources\shared\slre\*; DestDir: {app}\sources\shared\slre; Components: source
Source: sources\shared\cl\*; DestDir: {app}\sources\shared\cl; Components: source
Source: sources\shared\cl-sources\*; DestDir: {app}\sources\shared\cl-sources; Components: source
Source: sources\daemon\*; DestDir: {app}\sources\daemon; Components: source
Source: sources\session\*; DestDir: {app}\sources\session; Components: source
Source: sources\shlex\*; DestDir: {app}\sources\shlex; Components: source


[Icons]
Name: {group}\Setup KpyM Telnet SSH Server; Filename: {app}\daemon.exe; Parameters: -setup; IconFilename: {app}\daemon.exe
Name: {group}\KTS home!; Filename: {app}\KTS home.url; IconFilename: {app}\daemon.exe
Name: {group}\Uninstall KTS; Filename: {uninstallexe}


[Run]
Filename: {app}\fixscut.bat
Filename: "{app}\install.once.bat"; Parameters: "{code:InstallType}";


[UninstallDelete]
Type: filesandordirs; Name: {app}\log\ip-ban
Type: filesandordirs; Name: {app}\log\active-sessions
Type: filesandordirs; Name: {app}\log
Type: filesandordirs; Name: {app}\scripts
Type: filesandordirs; Name: {app}\sources
Type: filesandordirs; Name: {app}\subsystems
Type: filesandordirs; Name: {app}

[UninstallRun]
Filename: {app}\uninstall.bat

[Code]
var
InstallTypePage: TInputOptionWizardPage;
procedure InitializeWizard;
begin
{ Create the pages }
InstallTypePage := CreateInputOptionPage(wpSelectProgramGroup,
'Startup type', 'Select KTS startup type?',
'Select KTS startup type. Click Next to continue.',
True, False);
InstallTypePage.Add('Start KTS as SSH Server(port 22)');
InstallTypePage.Values[0] := True;
InstallTypePage.Add('Start KTS as Telnet Server(port 23)');
end;

function InstallType(Param: String): String;
begin
if( InstallTypePage.Values[0] = True ) then
Result := 'ssh'
else
Result := 'telnet'
end;


 

© 2007 - 2008 Kroum Grigorov
Powered by phpBB © 2001, 2005 phpBB Group